***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*JUL 19, 2019                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt BZX84C10TW A K 
.param
+vc0 = 9.603e-11 	vc1 = 1.812e-11		vc2 = 6.687e-12		vc3 = 3.667e-1
+tc1 = 1.659e-2		tc2 = 1.695e-2		tc3 = 7.559e-4		tc4 = 2.395e-4
d1 A K zener
g1 K A value = {(vc0+vc1*v(K,A))*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+vc2*exp(vc3*v(K,A))*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
.model zener d
***** flag parameter *****
+level = 1
***** dc model parameter *****
+ is = 1.740e-15           n = 1.042		  rs = 6.053e-1		 ikf = 1.70e-3
+ibv = 5e-3		 nbv = 1		  bv = 10
***** capacitance parameter *****
+cjo = 4.586e-11	   m = 3.288e-1		  vj = 5.255e-1
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25		  eg =1.172		 xti = 3
+trs1 = -5.805e-4	trs2 = -4.051e-6	tikf = 1.2e-2		
+tbv1 = 5.853e-4	tbv2 = -0.486e-7
.ends BZX84C10TW
*$
